VB.NET

.NET Array Dictionary List String Sub ArrayList Cast Class Console Dates DataTable DateTime Enum File For Format If IndexOf Lambda LINQ Nothing Parse Process Property Regex Replace Select Sort Split StringBuilder Substring

Subs, functions. In VB.NET, Subs and Functions contain behavior. A Sub procedure returns no value. Functions return a value, often based on a variable.


Parameters. Procedures optionally have argument lists and formal parameters. A parameter influence a procedure's behavior. Parameters can be passed ByVal or ByRef.

ByVal, ByRef

ByVal: The parameter's location is local. When chanced in a procedure body, no other values are affected.

ByRef: The parameter's location is shared with the calling location. A change is reflected outside the procedure.


Example sub. We declare and call a Sub procedure. We use different syntaxes to call the procedure. The program also shows XML comments. Subroutines return no value to the caller.

Result: This program uses Console.WriteLine and prints ten numbers to the console screen.

Tip: Please notice how the underscore character is used. It allows a line break to occur in a Sub call.

Based on: .NET 4

VB.NET program that uses Sub procedure

Module Module1

    Sub Main()
	'
	' Call the Sub Procedure, which returns no value.
	' ... You can put all the arguments on one line.
	'
	WriteArguments(1, 2, 3, 4, 5)
	'
	' Call the Sub Procedure again.
	' ... You can use the line continuation marker to break up the lines.
	'
	WriteArguments(1000, _
	    2000, _
	    3000, _
	    4000, _
	    5000)
    End Sub

    ''' <summary>
    ''' Prints out the five arguments.
    ''' </summary>
    ''' <param name="param1">Description 1.</param>
    ''' <param name="param2">Description 2.</param>
    ''' <param name="param3">Description 3.</param>
    ''' <param name="param4">Description 4.</param>
    ''' <param name="param5">Description 5.</param>
    ''' <remarks>Made by Dot Net Perls.</remarks>
    Sub WriteArguments(ByVal param1 As Integer, _
		       ByVal param2 As Integer, _
		       ByVal param3 As Integer, _
		       ByVal param4 As Integer, _
		       ByVal param5 As Integer)
	Console.WriteLine(param1)
	Console.WriteLine(param2)
	Console.WriteLine(param3)
	Console.WriteLine(param4)
	Console.WriteLine(param5)
    End Sub

End Module

Output

1
2
3
4
5
1000
2000
3000
4000
5000

Some notes. Above we see a method called WriteArguments. The Main Sub first calls the WriteArguments subroutine with a single line of arguments.

Note: The WriteArguments sub prints 5 integers on separate lines. Console.WriteLine, too, is a Sub.

Underscore: Next, we can separate a long line when calling or declaring a function. We use an underscore as a line continuation.


XML comments. To add an XML-based comment to a function, type three single-quote characters. Then insert the text inside the XML tags that appear.

Info: XML comments are used in Visual Studio's interface. They make large programs easier to develop.


Dim, As. We use the Dim and As keywords within a method body. Dim begins a variable declaration. And with As we specify that variable's type.

Dim: Here we declare a variable with the identifier (name) of "value." We assign it initially to 100.

As: This lets us specify the type of the variable. Sometimes this keyword is not required—the compiler can determine the types itself.

VB.NET program that uses Dim, As for local

Module Module1

    Sub Main()
	' The Dim keyword is used to declare a variable.
	' ... With As we specify its type.
	Dim value As Integer = 100
	Console.WriteLine(value)
    End Sub

End Module

Output

100

Functions. Let us contrast the Function type to the Subtype. The Sub does not return a value to its caller. But a Function returns a value.

Function
VB.NET program that uses Function

Module Module1

    Function MultiplyByTwo(ByVal test As Integer) As Integer
	Return test * 2
    End Function

    Sub Main()
	' Call the Function with an argument of 5.
	Console.WriteLine(MultiplyByTwo(5))
    End Sub

End Module

Output

10

As-keyword. In VB.NET, the As-keyword is used to indicate a type. In a parameter, As describes the type of the parameter. And in a Function, As describes the return value's type.


Multiple return values. Only one value can be placed in a Return statement. To return many values, we can use ByRef arguments or return a Tuple or KeyValuePair.

Multiple Return Values

Shared. A Function or Sub can be shared throughout all instances of the enclosing class. An instance reference is not needed to call a Shared Function.

Shared
VB.NET program that calls Shared Sub

Class Utility
    ''' <summary>
    ''' Displays a helpful message.
    ''' </summary>
    Public Shared Sub Message()
	Console.WriteLine("Hello world")
    End Sub
End Class

Module Module1
    Sub Main()
	' We do not use a Utility instance to call the shared Sub.
	Utility.Message()
    End Sub
End Module

Output

Hello world

A comment is best written at the level of intention. We explain what the code is meant to accomplish. Comments that simply translate the code to English are less effective.

But: Comments sometimes help emphasize certain aspects of programs. If a computation is important, a comment makes it more prominent.

VB.NET program that uses comments

Module Module1
    REM This is Module1.

    ''' <summary>
    ''' This is an XML comment.
    ''' </summary>
    ''' <remarks>Called at program start.</remarks>
    Sub Main()
	REM Get square root of 225.
	Dim value As Double = Math.Sqrt(225)

	' Print value. (Other comment syntax.)
	' ... Sometimes it helps to indent comments.
	Console.WriteLine(value)
    End Sub
End Module

Output

15

Comment syntax. We use three comment syntax forms. REM stands for an explanatory remark. All characters following REM are not code statements.

And: When three apostrophes are at the start of the comment, this is an XML comment.

XML comments: These are used by Visual Studio to help programmers navigate and discover your code. Certain XML tags can be added.

Apostrophe: The simplest comment form starts with a single apostrophe. This is probably the easiest syntax for comments.


Underscore. This language does not allow line breaks everywhere. A newline signals the end of a statement. But an underscore allows a statement to span many lines.

First: The first program uses a statement on a single line. This statement uses generic types.

Second: The second program uses the underscore syntax at the end of lines. This means the statement can continue on the next line.

VB.NET program that uses long statement

Module Module1

    Sub Main()
	Dim longerVariableName As Dictionary(Of String, KeyValuePair(Of Boolean, ....
	longerVariableName("a") = Nothing
    End Sub

End Module

VB.NET program that uses with statement on multiple lines

Module Module1

    Sub Main()
	Dim longerVariableName _
	    As Dictionary(Of String, KeyValuePair(Of Boolean, Integer)) = _
	    New Dictionary(Of String, KeyValuePair(Of Boolean, Integer))(5000)
	longerVariableName("a") = Nothing
    End Sub

End Module

AddressOf. This operator allows us to reference a Function or Sub by its name. We can then pass the result to another Function. Here, Array.FindIndex requires a Predicate argument.

AddressOf

Note: The AddressOf IsMatch syntax returns a suitable function as a Predicate instance.

Note 2: With AddressOf we can change a Function or Sub name into an argument, a variable, that we can pass to other procedures.

VB.NET that uses AddressOf

Module Module1

    Function IsMatch(ByVal item As String) As Boolean
	Return item.Length = 4
    End Function

    Sub Main()
	Dim items() As String = {"cat", "apple", "baby"}
	' Use AddressOf to specify IsMatch as the Predicate.
	Dim index As Integer = Array.FindIndex(items, AddressOf IsMatch)
	Console.WriteLine(index)
    End Sub

End Module

Output

2

ParamArray. This keyword allows a method to be called with an array of values that are specified directly (not in an explicit array). The values are placed into an array by the compiler.

Here: PrintValues receives a ParamArray. We can call it with zero, one or many arguments.

Warning: For performance, avoiding ParamArray is often a better solution. An array is created for each call to a ParamArray method.

VB.NET that uses ParamArray argument

Module Module1

    Sub PrintValues(ParamArray values() As Integer)
	' Display Length of array.
	Console.WriteLine("Count: " + values.Length.ToString())

	' Loop over ParamArray values.
	For Each value As Integer In values
	    Console.WriteLine(value)
	Next
    End Sub

    Sub Main()
	' Use ParamArray method.
	PrintValues()
	PrintValues(1)
	PrintValues(10, 20, 30)
    End Sub

End Module

Output

Count: 0
Count: 1
1
Count: 3
10
20
30

Extension. An extension method is not an instance method. But it is called with the same syntax as one. We apply the <Extension()> syntax.

Extension Method

Lambda expressions. We can use the Sub and Function keywords to declare lambda expressions directly in other method bodies. Lambdas act like any other method.

Lambdas

Recursion. When a Function calls itself, recursion occurs. The ByRef keyword can be useful when implementing recursive algorithms.

Recursion

With. The VB.NET language has some syntactic sugar. One example is the With statement. This reduces the typing necessary in some contexts.

With

Const. A Const value is used with syntax similar to a field or local variable. But it cannot be reassigned. It can only be initialized.

Const

Structures. When a method is called, a structure argument is copied fully to the method's local memory. A Class argument is not—only its reference is copied.

Structure, Arguments

In algorithms, we combine data structures and functions to achieve complex tasks. An algorithm is a well-known (or complex) method.

Fibonacci: We compute the Fibonacci sequence in VB.NET with a simple For-loop. Each number is the sum of the previous two.

Fibonacci Sequence

Levenshtein: With this algorithm, we compute the "edit distance" between two strings. This tells us string similarity.

Levenshtein

Procedures are everywhere. The Sub procedure syntax is often used in VB.NET programs. Subroutines (Subs) return no value. We compared Subs with Functions.